#NoEnv	; 빈변수 확인 방지?
#Persistent	; 실행 유지(ExitApp로 꺼짐)
#SingleInstance force	; 중복실행시 다시 실행

SetBatchLines,-1	; 스크립트 실행속도 최대

; 변수 두는곳
sts = show
enter = 0
toggle = on

; 함수 두는곳
sendH(sAnsiText)	; 한글을 깨지지 않고 입력해주는 함수
{
	wStrLen := DllCall("MultiByteToWideChar",uint,0,uint,0,str,sAnsiText,uint,-1,str,0,uint,0)
	varSetCapacity(cu_WideText,wStrLen*2,0)
	DllCall("MultiByteToWideChar",uint,0,uint,0,str,sAnsiText,uint,-1,str,cu_WideText,uint,wStrLen)
	nEventCount :=  wStrLen* 2,VarSetCapacity(events,28*nEventCount,0)
	ptrWCode := &cu_WideText,p := &events
	loop,% wStrLen-1
	{
		code := *ptrWCode|(*(ptrWCode+1)<<8),ptrWCode+=2
		p := NumPut(4,NumPut(code,NumPut(1,p+0)+2,0,"UShort")+0)+16
		p := NumPut(6,NumPut(code,NumPut(1,p+0)+2,0,"UShort")+0)+16
	}
	result := DllCall("SendInput","uint",nEventCount,"uint",&events,"int",28)
	If(ErrorLevel or result < nEventCount)
	{
		MsgBox,[SendInput] failed: EL = %ErrorLevel% ~ %result% of %nEventCount%
		return,false
	}
	return,true
}

; 트래이 메뉴 생성
Menu,Tray,NoStandard	; 오토핫키 트래이 기본 메뉴 삭제
Menu,Tray,Add,보이기/감추기,GuiShowHide	; 메뉴 추가
Menu,Tray,Add,ON/OFF,토글
Menu,Tray,Add,만든이 : joyfuI,블로그
Menu,Tray,Add,닫기,GuiClose
Menu,Tray,Default,보이기/감추기	; 트래이 아이콘 클릭시 작동할 기본 메뉴
Menu,Tray,Click,1	; 트래이 아이콘 한번 클릭으로 기본메뉴 작동
Menu,Tray,ToggleCheck,보이기/감추기	; 보이기/감추기 메뉴를 토글로 설정
Menu,Tray,ToggleCheck,ON/OFF	; ON/OFF 메뉴를 토글로 설정

; gui창 생성
Gui,Add,Hotkey,x10 y10 w50 v핫키,``
Gui,Add,Button,x+5 w70 h20 g적용,핫키 적용
Gui,Add,Text,x13 y+10,접두어
Gui,Add,Edit,x+10 y35 w70 v접두어
Gui,Add,Text,x13 y+10,접미어
Gui,Add,Edit,x+10 y60 w70 v접미어
Gui,Add,Button,x10 y+5 w40 h20 g토글,ON
Gui,Add,Text,x+5 y90 g블로그,만든이 : joyfuI
Gui,Show,xCenter yCenter w145 h110,자동 접두어&접미어 입력기

Gui,Submit,Nohide
Hotkey,%핫키%,토글
Hotkey,Enter,시작	; 엔터 키에 핫키 지정
Return

GuiShowHide:	; 창 숨기고 보이는 부분
Menu,Tray,ToggleCheck,보이기/감추기
If sts = show
{
	Gui,Hide
	sts = hide
	Return
}
If sts = hide
{
	Gui,Show
	sts = show
	Return
}
Return

GuiSize:	; 창변화시
If ErrorLevel = 1	; 최소화면
{
	Gui,Hide	; 창을 숨긴다
	Menu,Tray,ToggleCheck,보이기/감추기
	sts = hide
}
Return

GuiClose:	; 창닫을시
ExitApp	; 프로그램 종료
Return

시작:
Gui,Submit,Nohide	; gui 값 읽고
If enter = 0	; 엔터를 처음 치면
{
	SendInput {Enter}	; 엔터를 치고
	sendH(접두어)	; 접두어 입력
	enter = 1	; enter를 1로 수정(두번째라는거 표시)
	Return
}
If enter = 1	; 두번째 엔터는
{
	sendH(접미어)	; 접미어 입력뒤
	SendInput {Enter}	; 엔터
	enter = 0	; 다시 초기화..
	Return
}
Return

토글:
Menu,Tray,ToggleCheck,ON/OFF
Hotkey,Enter,toggle
If toggle = on
{
	GuiControl,,ON,OFF
	toggle = off
	Return
}
If toggle = off
{
	GuiControl,,OFF,ON
	toggle = on
	enter = 0	; 다시 활성화 시킬때 초기화
	Return
}
Return

적용:	; 핫키 적용하는 부분
If 핫키 != 	; 핫키 입력이 비어있지 않으면
	Hotkey,%핫키%,토글,off	; 이전핫키 끄고
Gui,Submit,Nohide	; gui 값 읽은뒤
If 핫키 != 	; 핫키 입력이 비어있지 않으면
	Hotkey,%핫키%,토글,on	; 핫키 지정
Return

블로그:
Run http://joyfui.wo.tc/840	; 블로그로 이동
Return